51 lines
1.8 KiB
Bash
51 lines
1.8 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
|
|
# Contributor: Johannes Dewender arch at JonnyJD dot net
|
|
# Contributor: Ivan Sichmann Freitas <ivansichfreitas@gmail.com>
|
|
# Contributor: Brice Maron <brice@bmaron.net>
|
|
# Contributor: Nuno Araujo <nuno.araujo at russo79.com>
|
|
# Contributor: Steven Allen <steven {at} stebalien {dot} com>
|
|
|
|
pkgname=python-keyring
|
|
_name=keyring
|
|
pkgver=25.5.0
|
|
pkgrel=2
|
|
pkgdesc='Store and access your passwords safely'
|
|
arch=(any)
|
|
url='https://github.com/jaraco/keyring'
|
|
license=('PSF-2.0' 'MIT')
|
|
depends=('python-jaraco.classes' 'python-secretstorage' 'python-jaraco.functools' 'python-jaraco.context')
|
|
makedepends=('python-build' 'python-installer' 'python-setuptools-scm' 'python-wheel')
|
|
checkdepends=('python-pytest' 'python-pyfakefs')
|
|
optdepends=('python-keyrings-alt: Alternative backends'
|
|
'python-dbus: kwallet backend')
|
|
source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
|
|
sha512sums=('bd8b792781bde9bb5d609acd9516b66486bd785231b81239bf9add483aefaa864ebe541d30c9977216c7a635e3f9161a55da15ba1070d8aab06bb86769fca476')
|
|
b2sums=('9499adbc756a94761acadf121ff22f55186481788477b17dcdb206200ab8041c9b68fba64139f823d1155e0c679f028281fc0093e1038b3cfd740c7c3e38fb7b')
|
|
|
|
build() {
|
|
cd $_name-$pkgver
|
|
|
|
python -m build --wheel --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd $_name-$pkgver
|
|
|
|
rm tests/backends/test_{Windows,macOS}.py
|
|
python -m pytest \
|
|
--deselect tests/backends/test_chainer.py
|
|
}
|
|
|
|
package() {
|
|
cd $_name-$pkgver
|
|
|
|
python -m installer -d "$pkgdir" dist/*.whl
|
|
install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
|
|
|
|
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
|
|
rm -rf "$pkgdir"/$site_packages/keyring/tests
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|