54 lines
2.6 KiB
Bash
54 lines
2.6 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
|
|
# Maintainer: Morten Linderud <foxboron@archlinux.org>
|
|
# Contributor: Dave Reisner <dreisner@archlinux.org>
|
|
# Contributor: Thomas Bächler <thomas@archlinux.org>
|
|
|
|
pkgname=mkinitcpio
|
|
pkgver=39.2
|
|
pkgrel=2.1
|
|
pkgdesc="Modular initramfs image creation utility"
|
|
arch=(any)
|
|
url='https://gitlab.archlinux.org/archlinux/mkinitcpio/mkinitcpio'
|
|
license=('GPL-2.0-only')
|
|
depends=('awk' 'mkinitcpio-busybox>=1.19.4-2' 'kmod' 'util-linux>=2.23' 'libarchive' 'coreutils'
|
|
'bash' 'binutils' 'diffutils' 'findutils' 'grep' 'filesystem>=2011.10-1' 'zstd' 'systemd')
|
|
checkdepends=('bats' 'bats-assert' 'lzop')
|
|
makedepends=('asciidoc')
|
|
optdepends=('gzip: Use gzip compression for the initramfs image'
|
|
'xz: Use lzma or xz compression for the initramfs image'
|
|
'bzip2: Use bzip2 compression for the initramfs image'
|
|
'lzop: Use lzo compression for the initramfs image'
|
|
'lz4: Use lz4 compression for the initramfs image'
|
|
'mkinitcpio-nfs-utils: Support for root filesystem on NFS')
|
|
provides=('initramfs')
|
|
backup=('etc/mkinitcpio.conf')
|
|
source=("https://sources.archlinux.org/other/$pkgname/$pkgname-$pkgver.tar.xz"{,.sig}
|
|
'0001-trigger.patch'
|
|
'mkinitcpio-archpower-support.patch')
|
|
sha512sums=('e4ba9fe901da56bb116510ec0c6abeba5153e57d9545baccbc466932951b7f324aa75ef7cc3de87f966456b0365b17552f367411d62585d500e88dc5c815058b'
|
|
'SKIP'
|
|
'b21e3961294e80bedd89a7e332ab11fc3b83eebfaf58d8f658e30f7d9caf2f84f4934224173c70f111932de8538fa327f5f6bfe9576b11bcbaf84d2d5ad8e85d'
|
|
'de907548a0fce2097fcbf5144f0ff9978c4d09622dd24113ebc217fea083591ed7c03623502c3d41cef5ba7f116afccf6a16dd38d737e4279cdac802c9dc5cb8')
|
|
b2sums=('7bd6bf491dd8b23d83e42834566375736cf8868d5120c7e24f4c8923eb03a64864cdda51d6a6f41373db88c29905535e4c8aa4bde172955bc7529e6b3ffc252c'
|
|
'SKIP'
|
|
'3b8e08d56e209ad11827d65595ab245bb680e72fb81139ba946e7610d16214c2a9022f1a1794e6797ef07fb0a43c5239167729225daf89396a8920f39f75e34b'
|
|
'84e4bedf946bbc5221d50c22e0523b8a83f2215b666d272497f67b5c54a4c89f44d849c0b934baf94dc9a5e3fc8062baaa145d84ebe106940c63073f5555a231')
|
|
validpgpkeys=('ECCAC84C1BA08A6CC8E63FBBF22FB1D78A77AEAB' # Giancarlo Razzolini
|
|
'C100346676634E80C940FB9E9C02FF419FECBE16') # Morten Linderud
|
|
|
|
prepare() {
|
|
cd "$pkgname-$pkgver"
|
|
patch -Np1 < ../0001-trigger.patch
|
|
|
|
patch -Np1 < ../mkinitcpio-archpower-support.patch
|
|
}
|
|
|
|
check() {
|
|
make -C "$pkgname-$pkgver" check
|
|
}
|
|
|
|
package() {
|
|
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
|
|
}
|