61 lines
1.7 KiB
Bash
61 lines
1.7 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Antonio Rojas <arojas@archlinux.org>
|
|
# Contributor: Tom Gundersen <teg@jklm.no>
|
|
# Contributor: Andrea Scarpino <andrea@archlinux.org>
|
|
# Contributor: ice-man <icemanf@gmail.com>
|
|
# Contributor: sergeantspoon <sergeantspoon@archlinux.us>
|
|
|
|
pkgbase=libssh
|
|
pkgname=(libssh
|
|
libssh-docs)
|
|
pkgver=0.11.1
|
|
pkgrel=1.1
|
|
pkgdesc='Library for accessing ssh client services through C libraries'
|
|
url='https://www.libssh.org/'
|
|
license=('LGPL-2.1-or-late')
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
depends=(glibc
|
|
openssl
|
|
zlib)
|
|
makedepends=(cmake
|
|
cmocka
|
|
doxygen
|
|
openssh
|
|
python)
|
|
provides=(libssh.so)
|
|
source=("https://www.libssh.org/files/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.asc})
|
|
sha256sums=('14b7dcc72e91e08151c58b981a7b570ab2663f630e7d2837645d5a9c612c1b79'
|
|
'SKIP')
|
|
validpgpkeys=('8DFF53E18F2ABC8D8F3C92237EE0FC4DCC014E3D' # Andreas Schneider <asn@cryptomilk.org>
|
|
'88A228D89B07C2C77D0C780903D5DF8CFDD3E8E7') # libssh release key (release key) <libssh@libssh.org>
|
|
|
|
build() {
|
|
cmake \
|
|
-B build \
|
|
-S $pkgname-$pkgver \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DWITH_GSSAPI=OFF \
|
|
-DUNIT_TESTING=ON
|
|
cmake --build build
|
|
cmake --build build --target docs
|
|
}
|
|
|
|
check() {
|
|
cmake --build build --target test
|
|
}
|
|
|
|
package_libssh() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
}
|
|
|
|
package_libssh-docs() {
|
|
pkgdesc='Documentation for libssh'
|
|
depends=()
|
|
provides=()
|
|
|
|
mkdir -p "$pkgdir"/usr/share/doc/libssh
|
|
cp -r build/doc/html "$pkgdir"/usr/share/doc/libssh
|
|
# cp -r build/doc/man "$pkgdir"/usr/share
|
|
# rm "$pkgdir"/usr/share/man/man3/{bug,deprecated}.*
|
|
}
|