50 lines
1.8 KiB
Bash
50 lines
1.8 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Clément Démoulins <clement@archivel.fr>
|
|
# Contributor: Fazlul Shahriar <fshahriar@gmail.com>
|
|
|
|
_pkgname=coveragepy
|
|
pkgname=python-coverage
|
|
pkgver=7.6.1
|
|
pkgrel=1
|
|
pkgdesc="A tool for measuring code coverage of Python programs"
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
url="https://coverage.readthedocs.io/en/latest/"
|
|
license=('Apache-2.0')
|
|
depends=('glibc' 'python')
|
|
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
|
|
checkdepends=('python-flaky' 'python-hypothesis'
|
|
'python-pytest' 'python-pytest-xdist'
|
|
'python-unittest-mixins' 'python-virtualenv')
|
|
source=("$pkgname-$pkgver.tar.gz::https://github.com/nedbat/coveragepy/archive/$pkgver.tar.gz")
|
|
sha512sums=('24eaf57a00ca862243c9ce705d312fe76fdc34bddf359b0f0fed191d0b1391244a95075a16de7af1a7988b48d304e5372151794d8ec82df573af43a70f2f0084')
|
|
b2sums=('a416b576ae623568b3ba96a8e4c8391d353b16d463d18590841db3ef67000a22ef7ad9fad131892bf83a3f96ad14e24b270bccf20be1335ba7fb53c313148cee')
|
|
|
|
build() {
|
|
cd $_pkgname-$pkgver
|
|
python -m build --wheel --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd $_pkgname-$pkgver
|
|
|
|
local python_version="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
|
|
(
|
|
virtualenv "test_dir" --system-site-packages
|
|
. "test_dir/bin/activate"
|
|
export PYTHONPATH="/usr/lib/python$python_version/site-packages:$PYTHONPATH"
|
|
export COVERAGE_NO_CONTRACTS=1
|
|
python setup.py --quiet clean develop
|
|
python igor.py zip_mods install_egg remove_extension
|
|
python igor.py test_with_tracer py
|
|
python setup.py --quiet build_ext --inplace
|
|
python igor.py test_with_tracer c
|
|
) || echo "Known failing tests."
|
|
}
|
|
|
|
package() {
|
|
cd $_pkgname-$pkgver
|
|
|
|
python -m installer --destdir="$pkgdir" dist/*.whl
|
|
}
|