67 lines
2.1 KiB
Bash
67 lines
2.1 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
|
|
# Contributor: kevin <kevin@archlinux.org>
|
|
# Contributor: John Proctor <jproctor@prium.net>
|
|
|
|
pkgname=graphviz
|
|
pkgver=12.1.1
|
|
pkgrel=1
|
|
pkgdesc='Graph visualization software'
|
|
url='https://www.graphviz.org/'
|
|
license=('EPL')
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
depends=('libltdl' 'gd' 'librsvg' 'ghostscript' 'pango' 'gts' 'gsfonts')
|
|
makedepends=('swig' 'guile' 'lua' 'perl' 'python' 'r' 'tk' 'qt6-base')
|
|
makedepends_powerpc=('mono')
|
|
makedepends_powerpc64le=('mono')
|
|
makedepends_x86_64=('mono')
|
|
optdepends=('guile: guile bindings'
|
|
'lua: lua bindings'
|
|
'perl: perl bindings'
|
|
'python: python bindings'
|
|
'r: r bindings'
|
|
'tcl: tcl bindings'
|
|
'qt6-base: gvedit'
|
|
'xterm: vimdot')
|
|
optdepends_powerpc64le=('mono: sharp bindings')
|
|
optdepends_powerpc64=('mono: sharp bindings')
|
|
optdepends_powerpc=('mono: sharp bindings')
|
|
optdepends_x86_64=('mono: sharp bindings')
|
|
|
|
source=("https://gitlab.com/graphviz/graphviz/-/archive/$pkgver/$pkgname-$pkgver.tar.gz"
|
|
'ghostscript918.patch')
|
|
sha256sums=('8fea54ab3ae6f2456df2f1ee8060f0262f2f4434c5b6ece2216777a2505a88e3'
|
|
'0083d126e27f2223ec4226fc1d71c9c84106968a0fdf65de838aee1e4882bfdb')
|
|
install=install
|
|
|
|
prepare() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
patch -p1 -i ../ghostscript918.patch
|
|
./autogen.sh NOCONFIG
|
|
}
|
|
|
|
build() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
export LIBPOSTFIX=/
|
|
export CXXFLAGS+=' -fPIC -fpermissive'
|
|
|
|
./configure --prefix=/usr \
|
|
--enable-python3=yes --disable-python --enable-lefty
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool # Fix overlinking
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}/${pkgname}-${pkgver}"
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
# fix symlink to symlink that doesn't get picked up by makepkg's zipman
|
|
ln -s gv2gxl.1.gz "${pkgdir}"/usr/share/man/man1/dot2gxl.1.gz
|
|
rm "${pkgdir}"/usr/share/man/man1/dot2gxl.1
|
|
|
|
# Deduplicates TCL libraries
|
|
cd "${pkgdir}/usr/lib/tcl8.6"
|
|
rm -fr graphviz
|
|
ln -s ../graphviz/tcl graphviz
|
|
}
|