42 lines
1.4 KiB
Bash
42 lines
1.4 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Jeremy "Ichimonji10" Audet <ichimonji10 at gmail dot com>
|
|
# Contributor: dnuux <dnuuxx@gmail.com>
|
|
|
|
pkgname=python-faker
|
|
pkgver=30.8.1
|
|
pkgrel=2
|
|
pkgdesc='Faker generates fake data for you.'
|
|
arch=(any)
|
|
url='https://faker.readthedocs.io/en/master/'
|
|
license=('MIT')
|
|
depends=('python-dateutil' 'python-typing_extensions')
|
|
optdepends=('python-xmltodict: for xml provider')
|
|
makedepends=('git' 'python-build' 'python-installer' 'python-pytest' 'python-setuptools' 'python-wheel')
|
|
checkdepends=('python-validators' 'python-ukpostcodeparser' 'python-freezegun' 'python-pillow'
|
|
'python-xmltodict')
|
|
source=("git+https://github.com/joke2k/faker.git#tag=v$pkgver")
|
|
sha512sums=('72e25b5948e2675d778e5281b974be87bffab961f7a49fc0c7c6fa45a7b807f14eb48f9695e5e18f4dd0ff627d5cf8501740b1089aa2c66d0d9825f2f296d925')
|
|
|
|
build() {
|
|
cd faker
|
|
python -m build --wheel --skip-dependency-check --no-isolation
|
|
}
|
|
|
|
check() {
|
|
cd faker
|
|
python setup.py egg_info
|
|
python -m pytest
|
|
}
|
|
|
|
package() {
|
|
cd faker
|
|
python -m installer --destdir="$pkgdir" dist/*.whl
|
|
|
|
# Symlink license file
|
|
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
|
|
install -d "$pkgdir"/usr/share/licenses/$pkgname
|
|
ln -s "$site_packages"/faker-$pkgver.dist-info/LICENSE.txt \
|
|
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
|
|
}
|