58 lines
1.7 KiB
Bash
58 lines
1.7 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Robin Broda <robin@broda.me>
|
|
# Contributor: Michael Lass <bevan@bi-co.net>
|
|
# Contributor: Justin Dray <justin@dray.be>
|
|
# Contributor: Patrick McCarty <pnorcks at gmail dot com>
|
|
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
|
|
# Contributor: Thomas S Hatch <thatch45 ar gmail dot com>
|
|
# Contributor: Michael P <ptchinster@archlinux.us>
|
|
# Contributor: Matt Heagney <matt@heagney.com>
|
|
|
|
pkgname=multipath-tools
|
|
pkgver=0.11.0
|
|
pkgrel=1
|
|
pkgdesc='Multipath tools for Linux (including kpartx)'
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
url='https://github.com/opensvc/multipath-tools'
|
|
license=('GPL-2.0-or-later' 'GPL-3.0-or-later' 'LGPL-2.0-or-later' 'LGPL-2.1-or-later')
|
|
depends=('glibc' 'gcc-libs' 'libaio' 'device-mapper' 'json-c' 'liburcu' 'systemd-libs' 'util-linux-libs')
|
|
makedepends=('git' 'systemd')
|
|
source=("multipath-tools::git+https://github.com/opensvc/multipath-tools#tag=${pkgver}"
|
|
multipath-tools-no-werror.patch)
|
|
sha256sums=('380a8333695103cf1a4546756eaf7daa13469832edac6f33b72fde8d51393e21'
|
|
'badfbeeba7859e1986de7ac53b7a34f4929100552f0f158a24091966dd9ca316')
|
|
|
|
_make_opts=(
|
|
prefix='/usr/'
|
|
bindir='/usr/bin'
|
|
etc_prefix=""
|
|
configfile='/etc/multipath.conf'
|
|
statedir='/etc/multipath'
|
|
LIB='lib'
|
|
WARN_ONLY=1
|
|
)
|
|
|
|
prepare() {
|
|
cd "${pkgname}"
|
|
patch -Np1 -i ${srcdir}/multipath-tools-no-werror.patch
|
|
}
|
|
|
|
build() {
|
|
cd "${pkgname}"
|
|
|
|
make \
|
|
"${_make_opts[@]}" \
|
|
FORTIFY_OPT=''
|
|
}
|
|
|
|
package() {
|
|
cd "${pkgname}"
|
|
|
|
make -j1 \
|
|
"${_make_opts[@]}" \
|
|
DESTDIR="${pkgdir}" \
|
|
install
|
|
|
|
install -D -m0644 -t "${pkgdir}/usr/share/doc/${pkgname}" README*
|
|
}
|