46 lines
1.8 KiB
Bash
46 lines
1.8 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
|
|
|
|
pkgname=python-openstacksdk
|
|
pkgver=3.3.0
|
|
pkgrel=2
|
|
pkgdesc="An SDK for building applications to work with OpenStack"
|
|
arch=(any)
|
|
url="https://developer.openstack.org/sdks/python/openstacksdk"
|
|
license=('Apache')
|
|
depends=('python-cryptography' 'python-decorator' 'python-dogpile.cache' 'python-iso8601'
|
|
'python-jmespath' 'python-jsonpatch' 'python-keystoneauth1' 'python-netifaces'
|
|
'python-os-service-types' 'python-pbr' 'python-platformdirs' 'python-yaml'
|
|
'python-requestsexceptions')
|
|
makedepends=('git' 'python-setuptools')
|
|
checkdepends=('python-ddt' 'python-fixtures' 'python-hacking' 'python-jsonschema'
|
|
'python-oslo-config' 'python-oslotest' 'python-prometheus_client'
|
|
'python-requests-mock' 'python-stestr' 'python-testscenarios' 'python-testtools')
|
|
source=("git+https://github.com/openstack/openstacksdk.git#tag=$pkgver")
|
|
sha512sums=('8208f59b846551f0252080ae8010cf887a3bf595541cd08d543a5dd1f23b6812ac02ccf62c4a9047373f8404bf514b56c90303b1d623c8102c1982908f543a9d')
|
|
|
|
build() {
|
|
cd openstacksdk
|
|
python setup.py build
|
|
}
|
|
|
|
check() {
|
|
# From https://github.com/openstack/openstacksdk/blob/master/tox.ini
|
|
export OS_LOG_CAPTURE=true OS_STDOUT_CAPTURE=true OS_STDERR_CAPTURE=true
|
|
|
|
# Deprecationwarnings break the tests, so we exclude these tests
|
|
# TestConnection.test_create_unknown_proxy and test_unsupported_version_override
|
|
|
|
cd openstacksdk
|
|
# TODO: package statsd?
|
|
stestr run --exclude-regex "openstack.tests.unit.test_stats.TestStats|test_unsupported_version_override|TestConnection.test_create_unknown_proxy"
|
|
}
|
|
|
|
package() {
|
|
cd openstacksdk
|
|
python setup.py install --root="$pkgdir" --optimize=1
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|