54 lines
1.9 KiB
Bash

# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Clément Démoulins <clement@archivel.fr>
# Contributor: Fazlul Shahriar <fshahriar@gmail.com>
_pkgname=coveragepy
pkgname=python-coverage
pkgver=6.5.0
pkgrel=5
pkgdesc="A tool for measuring code coverage of Python programs"
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
url="https://nedbatchelder.com/code/coverage/"
license=('Apache')
depends=('python')
optdepends=('python-tomli: for pyproject.toml support')
makedepends=('python-setuptools')
checkdepends=('python-flaky' 'python-hypothesis'
'python-pytest' 'python-pytest-xdist' 'python-tomli'
'python-unittest-mixins' 'python-virtualenv')
source=("$pkgname-$pkgver.tar.gz::https://github.com/nedbat/coveragepy/archive/$pkgver.tar.gz")
sha512sums=('40d8c1a6b796925e7c1082fe27398f160725be7f7b73afef6328080930b6b635bfae863ed303b262d530ccd46cc8c4ab823acc1998cdd21b686b9f81b01a16ff')
b2sums=('09d3efc0673485190c920c03f2fc1d2dac14c0759953df2d4f3e7043f63ea7b6c26ddcf715b6456671f3391bacefb34ed68228970faaf352ef6fd8ecb83413a7')
build() {
cd $_pkgname-$pkgver
python setup.py build
}
check() {
cd $_pkgname-$pkgver
local python_version="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
(
virtualenv "test_dir" --system-site-packages
. "test_dir/bin/activate"
export PYTHONPATH="/usr/lib/python$python_version/site-packages:$PYTHONPATH"
export COVERAGE_NO_CONTRACTS=1
python setup.py --quiet clean develop
python igor.py zip_mods install_egg remove_extension
python igor.py test_with_tracer py
python setup.py --quiet build_ext --inplace
python igor.py test_with_tracer c
) || echo "Known failing tests."
}
package() {
cd $_pkgname-$pkgver
python setup.py install --skip-build \
--optimize=1 \
--prefix=/usr \
--root="$pkgdir"
}