60 lines
2.1 KiB
Bash
60 lines
2.1 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
|
|
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
|
|
|
|
pkgname=swig
|
|
pkgver=4.3.0
|
|
pkgrel=1
|
|
pkgdesc="Generate scripting interfaces to C/C++ code"
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
url="http://www.swig.org/"
|
|
license=(
|
|
GPL-3.0-or-later
|
|
LicenseRef-BSD-Arizona
|
|
LicenseRef-BSD-Chicago
|
|
LicenseRef-BSD-Utah-California
|
|
)
|
|
depends=('gcc-libs' 'glibc' 'pcre2' 'zlib')
|
|
checkdepends=('ruby' 'python' 'java-environment' 'tcl' 'php' 'lua' 'r' 'go' 'boost')
|
|
source=($pkgname-$pkgver.tar.gz::https://github.com/swig/swig/archive/refs/tags/v$pkgver.tar.gz
|
|
https://github.com/swig/swig/commit/3d515751.patch)
|
|
sha512sums=('0a9bdcc4a28f1374f9e564fdb372f684bd277bf7b590491218c3538c230bcacd8de32365717a37cf5d7d02165dec9f3955e1bb1207181885fb5b7fbc7476ff04'
|
|
'5f205fbcb330f436579471865b8386dec58fb67569f97c9159bce0bcc1ee12924b4d8782f8808fafe5bf43ee6b9d961fb981eb4af0ef60b5cb6baee011745f7d')
|
|
|
|
prepare() {
|
|
sed -n '5,32p' $pkgname-$pkgver/LICENSE-UNIVERSITIES > LicenseRef-BSD-Utah-California.txt
|
|
sed -n '37,64p' $pkgname-$pkgver/LICENSE-UNIVERSITIES > LicenseRef-BSD-Chicago.txt
|
|
sed -n '69,94p' $pkgname-$pkgver/LICENSE-UNIVERSITIES > LicenseRef-BSD-Arizona.txt
|
|
|
|
# https://github.com/swig/swig/issues/2858
|
|
sed '/stl_no_default_constructor/d' -i $pkgname-$pkgver/Examples/test-suite/common.mk
|
|
|
|
# https://github.com/swig/swig/issues/2859
|
|
sed '/li_std_list/d' -i $pkgname-$pkgver/Examples/test-suite/java/Makefile.in
|
|
|
|
# Fix build of generated code with Werror=format-security
|
|
#patch -d $pkgname-$pkgver -p1 < 3d515751.patch
|
|
|
|
cd $pkgname-$pkgver
|
|
./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd ${pkgname}-${pkgver}
|
|
./configure --prefix=/usr
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd ${pkgname}-${pkgver}
|
|
make check PY3=y
|
|
}
|
|
|
|
package() {
|
|
cd ${pkgname}-${pkgver}
|
|
make DESTDIR="${pkgdir}" install
|
|
install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
|
|
install -D -m644 ../*.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
|
|
}
|