77 lines
2.6 KiB
Bash
77 lines
2.6 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Christian Hesse <mail@eworm.de>
|
|
# Contributor: Jonathan Conder <jonno.conder@gmail.com>
|
|
|
|
pkgbase='packagekit'
|
|
pkgname=('packagekit' 'libpackagekit-glib')
|
|
pkgver=1.3.0
|
|
pkgrel=2
|
|
pkgdesc='A system designed to make installation and updates of packages easier'
|
|
arch=(powerpc64le powerpc64 powerpc riscv64)
|
|
url='https://www.freedesktop.org/software/PackageKit/'
|
|
license=('GPL-2.0-or-later')
|
|
makedepends=('bash-completion'
|
|
'glib2-devel'
|
|
'gobject-introspection'
|
|
'intltool'
|
|
'meson'
|
|
'polkit'
|
|
'python-setuptools'
|
|
'sqlite'
|
|
'vala')
|
|
options=('!emptydirs')
|
|
validpgpkeys=('163EB50119225DB3DF8F49EA17ACBA8DFA970E17' # Richard Hughes <richard@hughsie.com>
|
|
'EC60AABDF42AAE8FB062640480858FA38F62AF74') # Kalev Lember <klember@redhat.com>
|
|
source=("https://www.freedesktop.org/software/PackageKit/releases/PackageKit-${pkgver}.tar.xz"
|
|
packagekit-alpm-15.patch
|
|
archpower.patch)
|
|
sha256sums=('f929a9be395e94ba5b0351c3e95f09212324af12b9c30a3a6d255c443b74e0e6'
|
|
'fb59657d36915c392e38173a6ad04de45eb646c1fd6288c2b76f5f1745a6f5ea'
|
|
'a986af7a4663d679031b3592a11207697cb0de8decb5573c1f56255af681bb53')
|
|
|
|
prepare() {
|
|
cd PackageKit-${pkgver}
|
|
patch -p1 -i ../packagekit-alpm-15.patch
|
|
|
|
patch -p1 -i ../archpower.patch
|
|
}
|
|
|
|
build() {
|
|
local _meson_options=(
|
|
-Dcron=false
|
|
-Dgstreamer_plugin=false
|
|
-Dgtk_doc=false
|
|
-Dgtk_module=false
|
|
-Dpackaging_backend=alpm
|
|
-Dsystemd=true
|
|
)
|
|
|
|
arch-meson "PackageKit-$pkgver" build "${_meson_options[@]}"
|
|
|
|
meson compile -C build
|
|
}
|
|
|
|
package_packagekit() {
|
|
depends=('libpackagekit-glib' 'pacman' 'libalpm.so' 'polkit' 'sqlite')
|
|
optdepends=('bash-completion: command completion in bash')
|
|
backup=('var/lib/PackageKit/transactions.db'
|
|
'etc/PackageKit/alpm.d/pacman.conf'
|
|
'etc/PackageKit/alpm.d/repos.list')
|
|
|
|
meson install -C build --destdir "$pkgdir"
|
|
|
|
# move away for libpackagekit-glib
|
|
mkdir -p libpackagekit/usr/{lib,share}
|
|
mv "$pkgdir"/usr/include/ libpackagekit/usr/
|
|
mv "$pkgdir"/usr/lib/{girepository-1.0,libpackagekit-glib2.so*,pkgconfig} libpackagekit/usr/lib/
|
|
mv "$pkgdir"/usr/share/{gir-1.0,vala}/ libpackagekit/usr/share/
|
|
}
|
|
|
|
package_libpackagekit-glib() {
|
|
pkgdesc='GLib library for accessing PackageKit'
|
|
depends=('glib2')
|
|
provides=('libpackagekit-glib2.so')
|
|
|
|
mv libpackagekit/usr/ "$pkgdir"/
|
|
}
|