50 lines
1.7 KiB
Bash
50 lines
1.7 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
|
|
# Contributor: SpepS <dreamspepser at yahoo dot it>
|
|
|
|
pkgname=openimageio
|
|
pkgver=2.5.17.0
|
|
pkgrel=4
|
|
pkgdesc="A library for reading and writing images, including classes, utilities, and applications"
|
|
arch=(x86_64 powerpc64le)
|
|
url="http://www.openimageio.org/"
|
|
license=('custom')
|
|
depends=('openexr' 'boost-libs' 'openjpeg2' 'glew' 'libtiff' 'opencolorio' 'libpng' 'libraw' 'libwebp'
|
|
'pugixml' 'pybind11' 'libheif' 'hdf5' 'freetype2')
|
|
# TODO: Consider adding these deps: 'openvdb' 'ffmpeg' 'ptex' 'opencv'
|
|
makedepends=('cmake' 'qt5-base' 'python' 'boost' 'mesa' 'fontconfig' 'libxrender' 'ninja' 'robin-map' 'fmt')
|
|
optdepends=('qt5-base: iv image viewer'
|
|
'python: bindings support')
|
|
source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenImageIO/oiio/archive/refs/tags/v$pkgver.tar.gz")
|
|
sha512sums=('a979d84ce985d80d42058ea9cdc631096ddcd712643eef497425e63f5d747cad0c5acb9a87af47be529f850c902f4bcaf33857fb3adec53e41a3d950d49a59d2')
|
|
|
|
build() {
|
|
cd OpenImageIO-$pkgver
|
|
|
|
local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
|
|
cmake \
|
|
-Bbuild \
|
|
-GNinja \
|
|
-DUSE_PYTHON=ON \
|
|
-DPYTHON_VERSION=$python_version \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_INSTALL_LIBDIR=lib \
|
|
-DOIIO_BUILD_TESTS=ON \
|
|
-DOIIO_BUILD_TOOLS=ON \
|
|
-DBUILD_MISSING_FMT=OFF \
|
|
-DUSE_EXTERNAL_PUGIXML=ON \
|
|
-DSTOP_ON_WARNING=OFF
|
|
ninja -C build
|
|
}
|
|
|
|
package() {
|
|
cd OpenImageIO-$pkgver
|
|
|
|
DESTDIR="$pkgdir" ninja -C build install
|
|
|
|
# Remove vendored fonts
|
|
rm -r "$pkgdir"/usr/share/fonts
|
|
|
|
install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE".md
|
|
}
|