89 lines
1.7 KiB
Bash
89 lines
1.7 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
|
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
pkgbase=librsvg
|
|
pkgname=(
|
|
librsvg
|
|
librsvg-docs
|
|
)
|
|
pkgver=2.59.2
|
|
pkgrel=1
|
|
epoch=2
|
|
pkgdesc="SVG rendering library"
|
|
url="https://wiki.gnome.org/Projects/LibRsvg"
|
|
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
|
license=(LGPL-2.1-or-later)
|
|
depends=(
|
|
cairo
|
|
dav1d
|
|
freetype2
|
|
gcc-libs
|
|
gdk-pixbuf2
|
|
glib2
|
|
glibc
|
|
harfbuzz
|
|
libxml2
|
|
pango
|
|
)
|
|
makedepends=(
|
|
cargo-c
|
|
gi-docgen
|
|
git
|
|
gobject-introspection
|
|
llvm
|
|
meson
|
|
python-docutils
|
|
rust
|
|
vala
|
|
)
|
|
checkdepends=(ttf-dejavu)
|
|
source=(
|
|
# librsvg tags use SSH signatures which makepkg doesn't understand
|
|
"git+https://gitlab.gnome.org/GNOME/librsvg.git#tag=$pkgver"
|
|
)
|
|
b2sums=('d806f7336282eb5a935c5c91b340ed5d9dcb6556f105138948f9f83774edc9de6bc9fd8591617b55e591d644c62ad09f8eccf092707ef11dcf1f93c513b86fbf')
|
|
|
|
# Use LTO
|
|
export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
|
|
|
|
# Use debug
|
|
export CARGO_PROFILE_RELEASE_DEBUG=2
|
|
|
|
prepare() {
|
|
cd librsvg
|
|
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
|
}
|
|
|
|
build() {
|
|
local meson_options=(
|
|
-D avif=enabled
|
|
)
|
|
|
|
arch-meson librsvg build "${meson_options[@]}"
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
meson test -C build --print-errorlogs --no-rebuild
|
|
}
|
|
|
|
package_librsvg() {
|
|
provides=(librsvg-${pkgver%%.*}.so)
|
|
|
|
meson install -C build --destdir "$pkgdir" --no-rebuild
|
|
|
|
mkdir -p doc/usr/share
|
|
mv {"$pkgdir",doc}/usr/share/doc
|
|
}
|
|
|
|
package_librsvg-docs() {
|
|
pkgdesc+=" (documentation)"
|
|
depends=()
|
|
|
|
mv doc/* "$pkgdir"
|
|
}
|
|
|
|
# vim:set sw=2 sts=-1 et:
|