51 lines
1.4 KiB
Bash
51 lines
1.4 KiB
Bash
# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
|
||
# Maintainer: Evangelos Foutras <foutrelis@archlinux.org>
|
||
|
||
pkgname=gn
|
||
pkgver=0.2207.ed1abc10
|
||
_commit=ed1abc107815210dc66ec439542bee2f6cbabc00
|
||
pkgrel=1
|
||
pkgdesc="Meta-build system that generates build files for Ninja"
|
||
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
|
||
url="https://gn.googlesource.com/gn/"
|
||
license=('BSD')
|
||
depends=('gcc-libs')
|
||
makedepends=('clang' 'ninja' 'python' 'git')
|
||
source=(git+https://gn.googlesource.com/gn#commit=$_commit)
|
||
sha256sums=('f051fd8181b1e8ebc1f9dc4f179effa9f0ad5aa14582cbaf9acb54483dc603e1')
|
||
|
||
pkgver() {
|
||
cd $pkgname
|
||
echo 0.$(git rev-list --count initial-commit..).$(git rev-parse --short=8 HEAD)
|
||
}
|
||
|
||
build() {
|
||
cd $pkgname
|
||
# works around:
|
||
# cc1plus: error: ‘-Wformat-security’ ignored without ‘-Wformat’ [-Werror=format-security]
|
||
export CXXFLAGS=${CXXFLAGS/-Werror=format-security/}
|
||
|
||
unset CFLAGS
|
||
./build/gen.py --allow-warnings
|
||
ninja -C out
|
||
}
|
||
|
||
check() {
|
||
cd $pkgname
|
||
./out/gn_unittests
|
||
}
|
||
|
||
package() {
|
||
cd $pkgname
|
||
install -D out/gn "$pkgdir/usr/bin/gn"
|
||
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*
|
||
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
|
||
|
||
mkdir -p "$pkgdir/usr/share/vim/vimfiles"
|
||
cp -r misc/vim/{autoload,ftdetect,ftplugin,syntax} \
|
||
"$pkgdir/usr/share/vim/vimfiles/"
|
||
install -Dm644 -t "$pkgdir/usr/share/emacs/site-lisp" misc/emacs/gn-mode.el
|
||
}
|
||
|
||
# vim:set ts=2 sw=2 et:
|