# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=tree-diff
pkgname=haskell-tree-diff
pkgver=0.1
pkgrel=86
pkgdesc="Diffing of (expression) trees"
url="https://github.com/phadej/tree-diff"
license=('BSD')
arch=(x86_64 powerpc64le)
depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-wl-pprint' 'haskell-ansi-terminal'
         'haskell-base-compat' 'haskell-hashable' 'haskell-parsers' 'haskell-quickcheck'
         'haskell-scientific' 'haskell-tagged' 'haskell-unordered-containers' 'haskell-uuid-types'
         'haskell-vector')
makedepends=('ghc' 'haskell-trifecta' 'haskell-tasty' 'haskell-tasty-golden'
             'haskell-tasty-quickcheck')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('a4ee703e4b6a18055c7749020863a9571af4620dbb7ea05903693c752e10e3ffa4fee8da0dacc0e4bbf92173e34c9070251881597ca1cd9f7c8ed365e840563c')

prepare() {
    cd $_hkgname-$pkgver
    echo -e "import Distribution.Simple\nmain = defaultMain" > Setup.hs
    sed -i -e 's/\^>=.*//' -e 's/&&.*//' -e '/bytestring-builder/d' $_hkgname.cabal
}

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}