From ff10aad2949f544c6a3079e97cbe5eb90abef411 Mon Sep 17 00:00:00 2001
From: kth5 <alex.bldck@gmail.com>
Date: Sun, 28 Jul 2024 15:35:24 +0200
Subject: [PATCH] * add dht

---
 dht/.SRCINFO | 14 ++++++++++++++
 dht/PKGBUILD | 33 +++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 dht/.SRCINFO
 create mode 100644 dht/PKGBUILD

diff --git a/dht/.SRCINFO b/dht/.SRCINFO
new file mode 100644
index 0000000000..85ad68a29b
--- /dev/null
+++ b/dht/.SRCINFO
@@ -0,0 +1,14 @@
+pkgbase = dht
+	pkgdesc = BitTorrent DHT library
+	pkgver = 0.27
+	pkgrel = 5
+	url = https://github.com/jech/dht
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	source = https://github.com/jech/dht/archive/refs/tags/dht-0.27.tar.gz
+	source = dht-cmake.patch::https://github.com/transmission/dht/commit/b02da598.patch
+	sha256sums = caba469a784a5c359c084099fdc025cfe09b1faec2ba9ba257b7384351c43c0a
+	sha256sums = 91fb75029bf04456bb7fd9c7cc14d544e906d35a309cc8de5be081049aeb7649
+
+pkgname = dht
diff --git a/dht/PKGBUILD b/dht/PKGBUILD
new file mode 100644
index 0000000000..6c33bb6ea1
--- /dev/null
+++ b/dht/PKGBUILD
@@ -0,0 +1,33 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Brett Cornwall <ainola@archlinux.org>
+# Contributor: Solomon Choina <shlomochoina@gmail.com>
+
+pkgname=dht
+pkgver=0.27
+pkgrel=5
+pkgdesc='BitTorrent DHT library'
+arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
+url='https://github.com/jech/dht'
+license=(MIT)
+makedepends=(cmake)
+source=(https://github.com/jech/dht/archive/refs/tags/$pkgname-$pkgver.tar.gz
+        dht-cmake.patch::https://github.com/transmission/dht/commit/b02da598.patch)
+sha256sums=('caba469a784a5c359c084099fdc025cfe09b1faec2ba9ba257b7384351c43c0a'
+            '91fb75029bf04456bb7fd9c7cc14d544e906d35a309cc8de5be081049aeb7649')
+
+prepare() {
+  patch -d dht-dht-$pkgver -p1 < dht-cmake.patch # Add cmake support
+}
+
+build() {
+  cmake -B build -S dht-dht-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_INCLUDEDIR=include/dht \
+    -DCMAKE_C_FLAGS="$CFLAGS -ffat-lto-objects"
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 dht-dht-$pkgver/LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}