* update spdlog to 1.14.1-3

spdlog/.SRCINFO

@@ -0,0 +1,21 @@
+pkgbase = spdlog
+	pkgdesc = Very fast, header-only/compiled, C++ logging library
+	pkgver = 1.14.1
+	pkgrel = 3
+	url = https://github.com/gabime/spdlog
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	makedepends = catch2
+	depends = gcc-libs
+	depends = glibc
+	depends = libfmt.so
+	provides = libspdlog.so
+	source = spdlog-1.14.1.tar.gz::https://github.com/gabime/spdlog/archive/v1.14.1.tar.gz
+	source = spdlog_fmt_external.patch
+	source = fix_build_with_fmt11.patch::https://github.com/gabime/spdlog/commit/d276069a6e916b1e1fd45885b15b72bd8ee000a7.patch
+	sha256sums = 1586508029a7d0670dfcb2d97575dcdc242d3868a259742b69f100801ab4e16b
+	sha256sums = a0eb34b7c6920f0db2587460071f53372663c191cdfe34bf5ea2704c309c745f
+	sha256sums = 9208168114b0996d6c4b74cfbdf145ed3209680bef258b9306467c39f1149202
+
+pkgname = spdlog

spdlog/.nvchecker.toml

@@ -0,0 +1,4 @@
+[spdlog]
+source = "git"
+git = "https://github.com/gabime/spdlog.git"
+prefix = "v"

spdlog/PKGBUILD

@@ -5,49 +5,57 @@
 
 pkgname=spdlog
 pkgver=1.14.1
-pkgrel=1
+pkgrel=3
 pkgdesc='Very fast, header-only/compiled, C++ logging library'
 arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
 url='https://github.com/gabime/spdlog'
 license=('MIT')
-depends=('libfmt.so')
-makedepends=('cmake')
+depends=(
+    'gcc-libs'
+    'glibc'
+    'libfmt.so'
+)
+makedepends=(
+    'cmake'
+    'catch2'
+)
 source=(
     "$pkgname-$pkgver.tar.gz::https://github.com/gabime/spdlog/archive/v$pkgver.tar.gz"
     "spdlog_fmt_external.patch"
+    "fix_build_with_fmt11.patch::https://github.com/gabime/spdlog/commit/d276069a6e916b1e1fd45885b15b72bd8ee000a7.patch"
 )
 provides=(
     'libspdlog.so'
 )
 sha256sums=('1586508029a7d0670dfcb2d97575dcdc242d3868a259742b69f100801ab4e16b'
-            'a0eb34b7c6920f0db2587460071f53372663c191cdfe34bf5ea2704c309c745f')
+            'a0eb34b7c6920f0db2587460071f53372663c191cdfe34bf5ea2704c309c745f'
+            '9208168114b0996d6c4b74cfbdf145ed3209680bef258b9306467c39f1149202')
 
 prepare() {
     cd "$pkgname-$pkgver"
     patch -p1 <../spdlog_fmt_external.patch
+    # Temporary upstream patch to fix build with fmt 11
+    patch -p1 <../fix_build_with_fmt11.patch
 }
 
 build() {
-    export CFLAGS+=" ${CPPFLAGS}"
-    export CXXFLAGS+=" ${CPPFLAGS}"
-    # FIXME: Stop -DSPDLOG_BUILD_TESTS=ON from downloading bundled catch2
     cmake -B build -S "$pkgname-$pkgver" \
         -DSPDLOG_BUILD_BENCH=OFF \
         -DSPDLOG_FMT_EXTERNAL=ON \
         -DSPDLOG_BUILD_SHARED=ON \
+        -DSPDLOG_BUILD_TESTS=ON \
         -DCMAKE_BUILD_TYPE=None \
         -DCMAKE_INSTALL_PREFIX=/usr \
         -DCMAKE_INSTALL_LIBDIR=lib \
         -Wno-dev
-    make -C build
+    cmake --build build
 }
 
-# See FIXME above
-#check() {
-#    make -C build test
-#}
+check() {
+    cmake --build build --target test
+}
 
 package() {
-    make -C build DESTDIR="$pkgdir" install
-    install -Dm644 "$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+    DESTDIR="$pkgdir" cmake --install build
+    install -vDm644 "$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
 }