* add sdl2_gfx

sdl2_gfx/.SRCINFO

@@ -0,0 +1,17 @@
+pkgbase = sdl2_gfx
+	pkgdesc = SDL graphics drawing primitives and other support functions (Version 2)
+	pkgver = 1.0.4
+	pkgrel = 4
+	epoch = 1
+	url = http://www.ferzkopp.net/wordpress/2016/01/02/sdl_gfx-sdl2_gfx/
+	arch = x86_64
+	arch = powerpc64le
+	arch = powerpc64
+	arch = powerpc
+	arch = riscv64
+	license = zlib
+	depends = sdl2
+	source = https://www.ferzkopp.net/Software/SDL2_gfx/SDL2_gfx-1.0.4.tar.gz
+	sha512sums = 81a100d3c8c3a7c6bd37a23f1290ff10685f8e62fbecd83b0086aae4edc721483e2153cd4219fbd9168f115eea0ea6b25f9be375faf5761f0babdfb1b52fe482
+
+pkgname = sdl2_gfx

sdl2_gfx/PKGBUILD

@@ -0,0 +1,33 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
+# Contributor: Jameson Pugh <imntreal@gmail.com>
+
+pkgname=sdl2_gfx
+pkgver=1.0.4
+pkgrel=4
+epoch=1
+pkgdesc="SDL graphics drawing primitives and other support functions (Version 2)"
+url="http://www.ferzkopp.net/wordpress/2016/01/02/sdl_gfx-sdl2_gfx/"
+arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
+license=(zlib)
+depends=(sdl2)
+source=("https://www.ferzkopp.net/Software/SDL2_gfx/SDL2_gfx-${pkgver}.tar.gz")
+sha512sums=('81a100d3c8c3a7c6bd37a23f1290ff10685f8e62fbecd83b0086aae4edc721483e2153cd4219fbd9168f115eea0ea6b25f9be375faf5761f0babdfb1b52fe482')
+
+build() {
+  cd SDL2_gfx-$pkgver
+
+  case "${CARCH}" in
+    x86_64) _configure_flags=(--enable-mmx) ;;
+    *)      _configure_flags=(--disable-mmx) ;;
+  esac
+
+  ./configure --prefix=/usr --build=${CHOST} ${_configure_flags[@]}
+  make
+}
+
+package() {
+  cd SDL2_gfx-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}