* update docbook-xsl 1.79.2

docbook-xsl/PKGBUILD

@@ -7,37 +7,49 @@
 
 pkgname=docbook-xsl
 pkgver=1.79.2
-pkgrel=4
+pkgrel=5
 pkgdesc='XML stylesheets for Docbook-xml transformations'
+url='https://docbook.org/'
 arch=(any)
 license=(custom)
-url='http://docbook.org/'
-depends=(libxml2 libxslt docbook-xml sed)
-install="$pkgname.install"
-source=("https://github.com/docbook/xslt10-stylesheets/releases/download/release%2F$pkgver/docbook-xsl-nons-$pkgver.tar.gz"
+install=$pkgname.install
+source=(https://github.com/docbook/xslt10-stylesheets/releases/download/release%2F$pkgver/docbook-xsl{,-nons}-$pkgver.tar.gz
         765567_non-recursive_string_subst.patch)
-sha256sums=('f89425b44e48aad24319a2f0d38e0cb6059fdc7dbaf31787c8346c748175ca8e'
+sha256sums=('966188d7c05fc76eaca115a55893e643dd01a3486f6368733c9ad974fcee7a26'
+            'f89425b44e48aad24319a2f0d38e0cb6059fdc7dbaf31787c8346c748175ca8e'
             '193ec26dcb37bdf12037ed4ea98d68bd550500c8e96b719685d76d7096c3f9b3')
 
 prepare() {
-  cd $pkgname-nons-$pkgver
+  cd $pkgname-$pkgver
+  patch -Np2 -i ../765567_non-recursive_string_subst.patch
+
+  cd ../$pkgname-nons-$pkgver
   patch -Np2 -i ../765567_non-recursive_string_subst.patch
 }
 
 package() {
-  cd $pkgname-nons-$pkgver
+  depends=(libxml2 libxslt docbook-xml)
 
-  _pkgroot="$pkgdir"/usr/share/xml/docbook/xsl-stylesheets-$pkgver
+  local pkgroot ns dir
+  for ns in -nons ''; do
+    pkgroot="$pkgdir/usr/share/xml/docbook/xsl-stylesheets-$pkgver$ns"
+    dir=$pkgname$ns-$pkgver
 
-  install -dm755 ${_pkgroot}
-  install -m644 VERSION VERSION.xsl ${_pkgroot}
+    install -Dt "$pkgroot" -m644 $dir/VERSION{,.xsl}
 
-  for fn in assembly common eclipse epub epub3 fo highlighting html htmlhelp javahelp lib \
-      manpages params profiling roundtrip template website xhtml xhtml-1_1 xhtml5; do
-          install -dm755 ${_pkgroot}/${fn}
-	  install -m644 ${fn}/*.{xml,xsl,dtd,ent} ${_pkgroot}/${fn} || true  # ignore missing files
+    (
+      shopt -s nullglob  # ignore missing files
+      for fn in assembly common eclipse epub epub3 fo highlighting html \
+        htmlhelp javahelp lib manpages params profiling roundtrip template \
+        website xhtml xhtml-1_1 xhtml5
+      do
+        install -Dt "$pkgroot/$fn" -m644 $dir/$fn/*.{xml,xsl,dtd,ent}
+      done
+    )
   done
 
-  install -dm755 "$pkgdir"/etc/xml
-  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -d "$pkgdir/etc/xml"
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $dir/COPYING
 }
+
+# vim:set sw=2 et:

docbook-xsl/docbook-xsl.install

@@ -0,0 +1,37 @@
+_xmlcatalog() {
+  xmlcatalog --noout "$@" etc/xml/catalog
+}
+
+post_install() {
+  [[ -f etc/xml/catalog ]] || _xmlcatalog --create
+
+  local ver x new=${1%-*}
+
+  for ver in $new current; do
+    for x in rewriteSystem rewriteURI; do
+      _xmlcatalog --add $x http://cdn.docbook.org/release/xsl/$ver \
+        /usr/share/xml/docbook/xsl-stylesheets-$new
+
+      _xmlcatalog --add $x http://docbook.sourceforge.net/release/xsl-ns/$ver \
+        /usr/share/xml/docbook/xsl-stylesheets-$new
+
+      _xmlcatalog --add $x http://docbook.sourceforge.net/release/xsl/$ver \
+        /usr/share/xml/docbook/xsl-stylesheets-$new-nons
+    done
+  done
+}
+
+post_upgrade() {
+  post_remove $2
+  post_install $1
+}
+
+post_remove() {
+  local old=${1%-*}
+  _xmlcatalog --del /usr/share/xml/docbook/xsl-stylesheets-$old
+  if (( $(vercmp $1 1.79.2-5) >= 0 )); then
+    _xmlcatalog --del /usr/share/xml/docbook/xsl-stylesheets-$old-nons
+  fi
+}
+
+# vim:set ft=sh sw=2 et: