* add hppa-unknown-linux-gnu-linux-api-headers

cross-compilers/hppa-unknown-linux-gnu-linux-api-headers/PKGBUILD

@@ -0,0 +1,32 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+_target_arch=hppa
+_target=${_target_arch}-unknown-linux-gnu
+pkgname=${_target}-linux-api-headers
+pkgver=6.8
+pkgrel=1
+pkgdesc="Kernel headers sanitized for use in userspace (${_target})"
+arch=(any)
+url='http://www.gnu.org/software/libc'
+license=(GPL2)
+makedepends=(rsync make)
+source=(https://www.kernel.org/pub/linux/kernel/v6.x/linux-${pkgver}.tar.xz)
+sha256sums=('c969dea4e8bb6be991bbf7c010ba0e0a5643a3a8d8fb0a2aaa053406f1e965f3')
+validpgpkeys=('ABAF11C65A2970B130ABE3C479BE3E4300411886'   # Linus Torvalds
+              '647F28654894E3BD457199BE38DBBDC86092693E')  # Greg Kroah-Hartman
+
+build() {
+  cd linux-${pkgver}
+
+  make ARCH=parisc mrproper
+}
+
+package() {
+  cd linux-${pkgver}
+  make INSTALL_HDR_PATH="$pkgdir/usr/$_target/usr" ARCH=parisc headers_install
+
+  # use headers from libdrm
+  rm -rf "$pkgdir/usr/$_target/usr/include/drm"
+
+  # clean-up unnecessary files generated during install
+  find ${pkgdir} \( -name .install -o -name ..install.cmd \) -delete
+}