* update python-dbus-deviation to 0.6.1-9

python/python-dbus-deviation/.SRCINFO

@@ -0,0 +1,22 @@
+pkgbase = python-dbus-deviation
+	pkgdesc = Parse D-Bus introspection XML and process it in various ways
+	pkgver = 0.6.1
+	pkgrel = 9
+	url = https://github.com/pwithnall/dbus-deviation
+	arch = any
+	license = LGPL-2.1-or-later
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-setuptools
+	makedepends = python-setuptools-git
+	makedepends = python-sphinx
+	makedepends = python-wheel
+	depends = python
+	depends = python-lxml
+	source = git+https://github.com/pwithnall/dbus-deviation#tag=0.6.1
+	source = unittest-deprecations.patch
+	sha256sums = d962dcd13ffd3c82ab92ceb2856916ea38ee1dab81d354e68ca34a41c88a3d2c
+	sha256sums = 14e81aef7e26feef6cd330fb85b264da5f173ccabc1d30f84bcfa49edf9734c2
+
+pkgname = python-dbus-deviation

python/python-dbus-deviation/.nvchecker.toml

@@ -0,0 +1,3 @@
+[python-dbus-deviation]
+source = "pypi"
+pypi = "dbus-deviation"

python/python-dbus-deviation/PKGBUILD

@@ -1,42 +1,51 @@
 # POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Carl Smedstad <carsme@archlinux.org>
 # Contributor: Eli Schwartz <eschwartz@archlinux.org>
 
-_pkgname=dbus-deviation
 pkgname=python-dbus-deviation
+_pkgname=${pkgname#python-}
 pkgver=0.6.1
-pkgrel=7
+pkgrel=9
 pkgdesc="Parse D-Bus introspection XML and process it in various ways"
 arch=(any)
-url="https://github.com/pwithnall/${_pkgname}"
-license=('LGPL')
-depends=('python-lxml')
-makedepends=('python-setuptools-git' 'python-sphinx')
-source=("https://files.pythonhosted.org/packages/source/${_pkgname:0:1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
-	"unittest-deprecations.patch")
-sha256sums=('e06b88efe223885d2725df51cf7c9b7b463d1c6f04ea49d4690874318d0eb7a3'
+url="https://github.com/pwithnall/dbus-deviation"
+license=('LGPL-2.1-or-later')
+depends=(
+  python
+  python-lxml
+)
+makedepends=(
+  git
+  python-build
+  python-installer
+  python-setuptools
+  python-setuptools-git
+  python-sphinx
+  python-wheel
+)
+source=(
+  "git+$url#tag=$pkgver"
+  "unittest-deprecations.patch"
+)
+sha256sums=('d962dcd13ffd3c82ab92ceb2856916ea38ee1dab81d354e68ca34a41c88a3d2c'
             '14e81aef7e26feef6cd330fb85b264da5f173ccabc1d30f84bcfa49edf9734c2')
-b2sums=('2042cb78bfd5ae259842001f39d8d10456c6b7aaac9bdde309895547c2e9649fac14e0a4a3a6432e3c67be562c443b2b44229e5c61e2802a10d8c66e94a544d4'
-        'edcda28e20cf604d26464f3288b777ee3fecb3135ef2d632bb1848d5c1d56eaf10b71c2bcb9277d1e8c9ed999d01e9c8a357e76bfa0cc83063a34576f2dd88e0')
 
 prepare() {
-   cd ${_pkgname}-${pkgver}
-   patch -Np1 -i ${srcdir}/unittest-deprecations.patch
+  cd "$_pkgname"
+  patch -Np1 -i ../unittest-deprecations.patch
 }
 
 build() {
-    cd ${_pkgname}-${pkgver}
-
-    python setup.py build
+  cd "$_pkgname"
+  python -m build --wheel --no-isolation
 }
 
 check() {
-    cd ${_pkgname}-${pkgver}
-
-    python -m unittest discover -vs dbusapi/tests
+  cd "$_pkgname"
+  python -m unittest discover -vs dbusapi/tests
 }
 
 package() {
-    cd ${_pkgname}-${pkgver}
-
-    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  cd "$_pkgname"
+  python -m installer --destdir="$pkgdir" dist/*.whl
 }