From 6152dc63ab1810beab45ca753279becfd4c1d5f7 Mon Sep 17 00:00:00 2001
From: kth5 <alex.bldck@gmail.com>
Date: Mon, 4 Sep 2023 16:47:21 +0200
Subject: [PATCH] * add gimp

---
 gimp/0001-no-check-update.patch | 14 ++++++
 gimp/PKGBUILD                   | 76 +++++++++++++++++++++++++++++++++
 gimp/gimp.install               |  8 ++++
 gimp/linux.gpl                  | 19 +++++++++
 4 files changed, 117 insertions(+)
 create mode 100644 gimp/0001-no-check-update.patch
 create mode 100644 gimp/PKGBUILD
 create mode 100644 gimp/gimp.install
 create mode 100644 gimp/linux.gpl

diff --git a/gimp/0001-no-check-update.patch b/gimp/0001-no-check-update.patch
new file mode 100644
index 0000000000..7a04225354
--- /dev/null
+++ b/gimp/0001-no-check-update.patch
@@ -0,0 +1,14 @@
+diff --git a/app/dialogs/about-dialog.c b/app/dialogs/about-dialog.c
+index 5db0fc4..8772eab 100644
+--- a/app/dialogs/about-dialog.c
++++ b/app/dialogs/about-dialog.c
+@@ -188,7 +188,9 @@ about_dialog_create (GimpCoreConfig *config)
+ #ifdef GIMP_UNSTABLE
+           about_dialog_add_unstable_message (children->data);
+ #endif /* GIMP_UNSTABLE */
++#ifdef CHECK_UPDATE
+           about_dialog_add_update (&dialog, config);
++#endif /* CHECK_UPDATE */
+         }
+       else
+         g_warning ("%s: ooops, no box in this container?", G_STRLOC);
diff --git a/gimp/PKGBUILD b/gimp/PKGBUILD
new file mode 100644
index 0000000000..6aead261bf
--- /dev/null
+++ b/gimp/PKGBUILD
@@ -0,0 +1,76 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Daniel Isenmann <daniel@archlinux.org>
+
+pkgname=gimp
+pkgver=2.10.34
+pkgrel=3
+pkgdesc='GNU Image Manipulation Program'
+url='https://www.gimp.org/'
+arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
+license=('GPL' 'LGPL')
+depends=(
+  # Core deps
+  'babl' 'cairo' 'fontconfig' 'freetype2' 'gcc-libs' 'gdk-pixbuf2' 'gegl' 'glib2' 'glibc' 'gtk2'
+  'harfbuzz' 'hicolor-icon-theme' 'iso-codes' 'json-glib' 'lcms2' 'libgexiv2' 'libmypaint'
+  'libunwind' 'mypaint-brushes1' 'pango' 'zlib'
+
+  # Plugins deps
+  'bzip2' 'libgudev' 'libheif' 'libjpeg-turbo' 'libjxl' 'libmng' 'libpng' 'librsvg' 'libtiff'
+  'libwebp' 'libwmf' 'libx11' 'libxcursor' 'libxext' 'libxfixes' 'libxmu' 'libxpm' 'openexr'
+  'openjpeg2' 'poppler-data' 'poppler-glib' 'xz'
+)
+makedepends=('alsa-lib' 'ghostscript' 'gtk-doc' 'gvfs' 'intltool')
+optdepends=('alsa-lib: for MIDI event controller module'
+            'ghostscript: for PostScript support'
+            'gutenprint: for sophisticated printing only as gimp has built-in cups print support'
+            'gvfs: for HTTP/S support (and many other schemes)')
+conflicts=('gimp-plugin-wavelet-decompose')
+replaces=('gimp-plugin-wavelet-decompose')
+install=gimp.install
+source=(https://download.gimp.org/pub/gimp/v${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2
+        0001-no-check-update.patch
+        linux.gpl)
+sha256sums=('84004642d351b398a4293cd7fd3592044a944f05bb52850ee6068f247c657aa3'
+            'ac3e8b44cf391f4ab3050652f2cc1f146f451fb25178d5a596d905f5bad13fcf'
+            '1003bbf5fc292d0d63be44562f46506f7b2ca5729770da9d38d3bb2e8a2f36b3')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+
+  patch -Np1 < ../0001-no-check-update.patch
+  autoreconf -vi
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/bin \
+    --enable-mp \
+    --enable-gimp-console \
+    --enable-gtk-doc \
+    --disable-check-update \
+    --disable-python \
+    --with-bug-report-url='https://bugs.archlinux.org/?string=gimp' \
+    --with-openexr \
+    --without-aa
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+
+  make DESTDIR="${pkgdir}" install
+  install -D -m644 "${srcdir}/linux.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/Linux.gpl"
+
+  rm "${pkgdir}/usr/share/man/man1/gimp-console.1"
+  ln -s gimp-console-${pkgver%.*}.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
+  ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
+  ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
+}
+
+# vim: ts=2 sw=2 et:
diff --git a/gimp/gimp.install b/gimp/gimp.install
new file mode 100644
index 0000000000..c211567137
--- /dev/null
+++ b/gimp/gimp.install
@@ -0,0 +1,8 @@
+#!/bin/bash
+
+post_upgrade() {
+  if [[ $(vercmp '2.10.18-4' "$2") -eq 1 ]]; then
+    echo ' > The python2 plugin support is disabled, you will need to install this'
+    echo ' > separately if you need it, e.g. the python2-gimp package in the AUR.'
+  fi
+}
diff --git a/gimp/linux.gpl b/gimp/linux.gpl
new file mode 100644
index 0000000000..0a73d89793
--- /dev/null
+++ b/gimp/linux.gpl
@@ -0,0 +1,19 @@
+GIMP Palette
+Name: linux
+#
+  0   0   0
+  0   0 170
+  0 170   0
+  0 170 170
+170   0   0
+170   0 170
+170  85   0
+170 170 170
+ 85  85  85
+ 85  85 255
+ 85 255  85
+ 85 255 255
+255  85  85
+255  85 255
+255 255  85
+255 255 255