* add pipewire

pipewire/PKGBUILD

@@ -0,0 +1,45 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgname=pipewire
+pkgver=0.2.5+3+g371da358
+pkgrel=1
+pkgdesc="Server and user space API to deal with multimedia pipelines"
+url="https://pipewire.org"
+license=(LGPL2.1)
+arch=(x86_64 powerpc64le)
+depends=(gstreamer gst-plugins-base v4l-utils sbc ffmpeg rtkit)
+makedepends=(git meson doxygen graphviz xmltoman valgrind)
+install=pipewire.install
+_commit=371da358d1580dc06218d18a12a99611cac39e4e  # master
+source=("git+https://github.com/PipeWire/pipewire#commit=$_commit")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Reduce docs size
+  printf '%s\n' >>doc/Doxyfile.in \
+    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D docs=true \
+    -D man=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

pipewire/pipewire.install

@@ -0,0 +1,14 @@
+post_install() {
+  # Enable socket by default
+  systemctl --global enable pipewire.socket
+}
+
+post_upgrade() {
+  if (( $(vercmp $2 0.1.6-2) < 0)); then
+    systemctl --global enable pipewire.socket
+  fi
+}
+
+pre_remove() {
+  systemctl --global disable pipewire.socket
+}