* add rofi

rofi/.SRCINFO

@@ -0,0 +1,24 @@
+pkgbase = rofi
+	pkgdesc = A window switcher, application launcher and dmenu replacement
+	pkgver = 1.7.5
+	pkgrel = 3
+	url = https://github.com/DaveDavenport/rofi
+	arch = x86_64
+	arch = powerpc64le
+	arch = powerpc64
+	arch = powerpc
+	arch = riscv64
+	license = MIT
+	makedepends = check
+	depends = libxdg-basedir
+	depends = startup-notification
+	depends = libxkbcommon-x11
+	depends = xcb-util-wm
+	depends = xcb-util-xrm
+	depends = librsvg
+	depends = xcb-util-cursor
+	optdepends = i3-wm: use as a window switcher
+	source = https://github.com/DaveDavenport/rofi/releases/download/1.7.5/rofi-1.7.5.tar.xz
+	sha256sums = caffcf66d165cb32b748c1db7f229d6d75da58c1685eb17455f65c60e8220c8d
+
+pkgname = rofi

rofi/.nvchecker.toml

@@ -0,0 +1,3 @@
+[rofi]
+source = "git"
+git = "https://github.com/DaveDavenport/rofi.git"

rofi/PKGBUILD

@@ -0,0 +1,49 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Morten Linderud <foxboron@archlinux.org>
+# Maintainer: Robin Candau <antiz@archlinux.org>
+# Contributor: Maxim Baz <$pkgname at maximbaz dot com>
+# Contributor: Anatol Pomozov
+# Contributor: Benjamin Chrétien <chretien + aur [at] lirmm [dot] fr>
+# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Contributor: Rasi <rasi@xssn.at>
+# Contributor: Sean Pringle <sean.pringle@gmail.com>
+# Contributor: SanskritFritz (gmail)
+
+pkgname=rofi
+pkgver=1.7.5
+pkgrel=3
+pkgdesc='A window switcher, application launcher and dmenu replacement'
+arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
+url="https://github.com/DaveDavenport/$pkgname"
+license=(MIT)
+depends=(libxdg-basedir startup-notification libxkbcommon-x11 xcb-util-wm xcb-util-xrm librsvg xcb-util-cursor)
+makedepends=(check)
+optdepends=('i3-wm: use as a window switcher')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.xz")
+sha256sums=('caffcf66d165cb32b748c1db7f229d6d75da58c1685eb17455f65c60e8220c8d')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  sed -i "s/xfce4-terminal.wrapper/xfce4-terminal/g" script/rofi-sensible-terminal
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  autoreconf -i
+  ./configure --prefix=/usr --sysconfdir=/etc
+  make
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  LC_ALL=C make check
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make install install-man DESTDIR="$pkgdir"
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname/examples"
+  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$pkgname/examples"
+}