# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Robert McCathie <archaur at rmcc dot com dot au>

pkgname=libwps
pkgver=0.4.14
pkgrel=2
pkgdesc="a Microsoft Works file word processor format import filter library"
arch=(x86_64 powerpc64le powerpc64 riscv64)
url="https://sourceforge.net/projects/libwps/"
license=('LGPL-2.1-or-later OR MPL-2.0')
depends=('libwpd' 'librevenge' 'gcc-libs' 'glibc')
makedepends=('doxygen')
source=("https://downloads.sourceforge.net/project/libwps/$pkgname/$pkgname-$pkgver/$pkgname-$pkgver.tar.xz")
sha1sums=('e6f057f9b55448bc630726d2a863871a830a7e75')
sha256sums=('365b968e270e85a8469c6b160aa6af5619a4e6c995dbb04c1ecc1b4dd13e80de')

build() {
	cd $pkgname-$pkgver
	./configure  --prefix=/usr \
	  --disable-static
	make
}

check() {
	cd ${pkgname}-${pkgver}
	make check
}

package() {
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install
}
