# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Maxime Gauduin <alucrydarchlinux.org>
# Contributor: Padfoot <padfoot@exemail.com.au>

pkgname=lightdm-gtk-greeter
pkgver=2.0.9
pkgrel=1
epoch=1
pkgdesc='GTK+ greeter for LightDM'
arch=(x86_64 powerpc64le powerpc riscv64)
url=https://github.com/Xubuntu/lightdm-gtk-greeter
license=(
  GPL3
  LGPL3
)
depends=(
  gtk3
  lightdm
)
makedepends=(
  exo
  git
  gobject-introspection
  intltool
  xfce4-dev-tools
)
backup=(etc/lightdm/lightdm-gtk-greeter.conf)
_tag=21295c70377ff4b006bfa8f10cc622c56fc0851e
source=(git+https://github.com/Xubuntu/lightdm-gtk-greeter.git#tag=${_tag})
sha256sums=(SKIP)

pkgver() {
  cd lightdm-gtk-greeter
  git describe --tags | sed 's/^lightdm-gtk-greeter-//'
}

prepare() {
  cd lightdm-gtk-greeter
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd lightdm-gtk-greeter
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib/lightdm \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --with-libxklavier \
    --enable-kill-on-sigterm \
    --disable-at-spi-command \
    --disable-indicator-services-command \
    --disable-libido \
    --disable-libindicator \
    --disable-static
  make
}

package() {
  make DESTDIR="${pkgdir}" -C lightdm-gtk-greeter install
}

# vim: ts=2 sw=2 et:
