# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=perl-data-munge
epoch=1
pkgver=0.111
pkgrel=1
pkgdesc="Various utility functions"
arch=(any)
license=('PerlArtistic')
url="https://metacpan.org/release/Data-Munge"
depends=('perl')
checkdepends=('perl-test2-suite')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/M/MA/MAUKE/Data-Munge-$pkgver.tar.gz")
sha512sums=('e09c62bf321b98b44a17c1991b31d7c5925f7aae5be36166596628d1257a57b42e58ca169208361e05e99a768b7c71cfb706a37d2e5d3657ea6171123fa512f6')

build() {
  cd Data-Munge-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd Data-Munge-$pkgver
  make test
}

package() {
  cd Data-Munge-$pkgver
  make DESTDIR="$pkgdir" install
}
