# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=perl-b-keywords
pkgver=1.27
pkgrel=2
pkgdesc="Lists of reserved barewords and symbol names"
arch=(any)
license=('PerlArtistic')
url="https://metacpan.org/release/B-Keywords"
depends=('perl')
checkdepends=('perl-test-pod')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/R/RU/RURBAN/B-Keywords-$pkgver.tar.gz")
sha512sums=('f846cbc6f045a8cc7cb9f7d74a50e927ba66b7060dc0f77c096f15fdb0d8959599dc8c2024eacea9ba298eac42bbfb887f6ca8b749531d8c08962de673d21854')

build() {
  cd B-Keywords-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd B-Keywords-$pkgver
  make test
}

package() {
  cd B-Keywords-$pkgver
  make DESTDIR="$pkgdir" install
}
