# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Thomas Baechler <thomas@archlinux.org>

pkgname=b43-fwcutter
pkgver=019
pkgrel=6
pkgdesc="firmware extractor for the b43 kernel module"
url="https://wireless.docs.kernel.org/en/latest/en/users/drivers/b43.html"
depends=('glibc')
license=('GPL-2.0-only')
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
source=("https://bues.ch/b43/fwcutter/${pkgname}-${pkgver}.tar.bz2"{,.asc})
sha256sums=('d6ea85310df6ae08e7f7e46d8b975e17fc867145ee249307413cfbe15d7121ce'
            'SKIP')
validpgpkeys=('757FAB7CED1814AE15B4836E5FB027474203454C') # Michael Büsch (Git tag signing key) <m@bues.ch>

build() {
	cd $pkgname-$pkgver
	make
}

package() {
	cd $pkgname-$pkgver
	install -D -m755 b43-fwcutter "$pkgdir"/usr/bin/b43-fwcutter
	install -D -m644 b43-fwcutter.1 "$pkgdir"/usr/share/man/man1/b43-fwcutter.1
}
