# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=perl-pod-spell
pkgver=1.26
pkgrel=4
pkgdesc="A formatter for spellchecking Pod"
arch=(any)
license=('PerlArtistic')
url="https://metacpan.org/release/Pod-Spell"
depends=('perl-class-tiny' 'perl-file-sharedir' 'perl-lingua-en-inflect' 'perl-path-tiny'
         'perl-pod-parser')
makedepends=('perl-file-sharedir-install' 'perl-test-deep')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/H/HA/HAARG/Pod-Spell-$pkgver.tar.gz")
sha512sums=('6fba5f6337fcd0e7f8df7d379e9d7a7de5ab13b748831c9f0e48cefbce9b1548d117d96db64693fc71519d700c397d217f27574359518b39225489b96c3c3c9e')

build() {
  cd Pod-Spell-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd Pod-Spell-$pkgver
  make test
}

package() {
  cd Pod-Spell-$pkgver
  make DESTDIR="$pkgdir" install
}
