# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>

pkgname=python-oslo-i18n
pkgver=6.4.0
pkgrel=1
pkgdesc="Oslo i18n library"
arch=(any)
url="https://pypi.python.org/pypi/oslo.i18n/$pkgver"
license=('Apache')
depends=('python-pbr')
makedepends=('git' 'python-setuptools')
checkdepends=('python-stestr' 'python-oslotest' 'python-testscenarios' 'python-oslo-config')
source=("git+https://github.com/openstack/oslo.i18n.git#tag=$pkgver"
        "fix-tests-extra-warning.patch")
sha512sums=('bb073c0dd7514f5459e35e38802ecfb69598242bf3df7a3c951c650249f26daa12f68275c7643c87d52ad6078f3e22c37999d99cc840c49c014c59a9c376a0f4'
            '445b03985fafef0e4db856afe54772bb8b23b328f0a0166277c5aba9e899e2c6596737c45c11f0581fa3093853048134eac1c894227e88be463a4d0affe849e8')

prepare() {
  cd oslo.i18n
  patch -Np1 -i ../fix-tests-extra-warning.patch
}

build() {
  cd oslo.i18n
  python setup.py build
}

check() {
  cd oslo.i18n
  stestr run
}

package() {
  cd oslo.i18n
  python setup.py install --root="$pkgdir" --optimize=1
}

# vim:set ts=2 sw=2 et:
