# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgname=xorg-xauth
pkgver=1.1.3
pkgrel=1
pkgdesc="X.Org authorization settings program"
arch=(x86_64 powerpc64le powerpc64 powerpc riscv64)
license=('MIT-open-group')
url="https://gitlab.freedesktop.org/xorg/app/xauth"
depends=('libxmu' 'libxau' 'libxext' 'libx11' 'glibc')
makedepends=('xorg-util-macros')
groups=('xorg-apps' 'xorg')
source=(https://xorg.freedesktop.org/releases/individual/app/xauth-${pkgver}.tar.xz{,.sig})
sha512sums=('536434f6c607673c00b9658ea591bf32419cc151d138f991ea38167220563519a6a84a5504003da15820f2a7ed50ea2449c6ce9c991d1446ee9a7305c647d694'
            'SKIP')
#validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88@gmail.com>
#validpgpkeys+=('995ED5C8A6138EB0961F18474C09DD83CAAA50B2') # "Adam Jackson <ajax@nwnk.net>"
validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # "Alan Coopersmith <alan.coopersmith@oracle.com>"

build() {
  cd xauth-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd xauth-${pkgver}
  make check
}

package() {
  cd xauth-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
